Behaviour module used to compose command pipelines.

Examples

A Simple Ping Command

  defmodule MyBot.Command.Ping do
    use Crux.Extensions.Command

    def triggers(), do: ["ping"]

    def call(command, _opts) do
      set_response(command, content: "Pong!")
    end
  end

A Simple Middleware Command

  defmodule MyBot.Middleware.FetchPicture do
    use Crux.Extensions.Command

    def call(command, opts) do
      # Default the type to :cat
      type = Keyword.get(opts, :type, :cat)

      case MyBot.Api.fetch_picture(type) do
        {:ok, picture} ->
          assign(command, :picture, picture)
        {:error, _error} ->
          command
          |> set_response(content: "An error occurred while fetching the picture.")
          # Halt the pipeline to stop any further execution of commands or middlewares
          |> halt()
      end
    end
  end

Using the Middleware Command

  defmodule MyBot.Command.Dog do
    use Crux.Extensions.Command

    def triggers(), do: ["dog"]

    # Specify the type of :dog
    def required(), do: [{MyBot.Middleware.FetchPicture, type: :dog}]

    def call(command, _opts) do
      set_response(command, content: "Your dog picture link: #{command.assigns.picture}")
    end
  end